;
; Script Omnimark para gerar uma página HTML com os arqueositios agrupados
;   por Concelho e links para cada uma das páginas individuais dos arqsits
; e cruzar esta informação com o glossário enriquecendo os dois.
; Versão 0.1 - jcr - 21.04.98
;

DOWN-TRANSLATE

global stream area-stream variable initial-size 0
global stream thesaurus variable initial-size 0
global stream cidenti
global stream concelho
global counter arqind INITIAL {1}
global stream farq

global stream glossario
  
global counter cliga 

ELEMENT #IMPLIED
  SUPPRESS

ELEMENT arqsits
  OUTPUT "%c"

ELEMENT arqelem
  set cliga to 1
  OPEN farq AS FILE "ARQS/arq%d(arqind).html"
  USING OUTPUT AS farq
    OUTPUT "<HR><P>%c<P><HR>"
  CLOSE farq
  INCREMENT arqind

ELEMENT identi
  SET cidenti TO "%c"
  OUTPUT "<P>%n<H3>Identificação:</H3> %g(cidenti)"

ELEMENT concel
  SET concelho TO "%sc"
  OUTPUT "<P>%n<H3>Concelho:</H3> %g(concelho)"
  DO WHEN !(area-stream has key concelho)
    NEW area-stream key concelho
  DONE
  REOPEN area-stream key concelho as buffer
  PUT area-stream key concelho "<LI><A HREF=%"ARQS/arq%d(arqind).html%">%g(cidenti)</A>%n"
  CLOSE area-stream key concelho

ELEMENT quadro
  OUTPUT "<P>%n<H3>Quadro:</H3>%n%c"

ELEMENT desarq
  OUTPUT "<P>%n<H3>Descrição:</H3>%n%c"

ELEMENT liga
  local stream lstemp

  set lstemp to "%c"
  OUTPUT "<A NAME=%"%g(cidenti)%d(cliga)%" HREF=%"gloss.html#%g(lstemp)%">%g(lstemp)</A>"
  DO WHEN !(thesaurus has key lstemp)
    new thesaurus key lstemp
  DONE
  REOPEN thesaurus key lstemp as buffer
  PUT thesaurus key lstemp "<LI><A HREF=%"arq%d(arqind).html#%g(cidenti)%d(cliga)%">%g(cidenti)</A>%n"
  CLOSE thesaurus key lstemp 
  INCREMENT cliga

DOCUMENT-END
  local stream alist

  REPEAT OVER area-stream
    OUTPUT "<h2>Entrys of  '" || 
           key of area-stream ||
           "':</h2>%n<ul>%n%g(area-stream)</ul>%n"
  again

  OPEN glossario as FILE "ARQS/gloss.html"
  PUT glossario "<hr><H1>THESAURUS:</H1>%n" 
  REPEAT OVER thesaurus
    PUT glossario "<h2><a name=%"" || key of thesaurus || "%">Termo:  '" || 
           key of thesaurus ||
           "'</a>:</h2>%n<ul>%n%g(thesaurus)</ul>%n"
  AGAIN 
  CLOSE glossario