;
; Script Omnimark para gerar uma página HTML com os arqueositios agrupados
;   por Concelho e links para cada uma das páginas individuais dos arqsits
; Versão 0.1 - jcr - 20.04.98
;

DOWN-TRANSLATE

global stream area-stream variable initial-size 0
global stream temp
global stream concelho
global counter arqind INITIAL {1}
global stream farq

ELEMENT #IMPLIED
  SUPPRESS

ELEMENT arqsits
  OUTPUT "%c"

ELEMENT arqelem
  OPEN farq AS FILE "ARQS/arq%d(arqind).html"
  USING OUTPUT AS farq
    OUTPUT "<HR><P>%c<P><HR>"
  CLOSE farq
  INCREMENT arqind
  

ELEMENT identi
  SET temp TO "%c"
  OUTPUT "<P>%n<H3>Identificação:</H3> %g(temp)"

ELEMENT concel
  SET concelho TO "%sc"
  OUTPUT "<P>%n<H3>Concelho:</H3> %g(concelho)"
  DO WHEN !(area-stream has key concelho)
    NEW area-stream key concelho
  DONE
  REOPEN area-stream key concelho as buffer
  PUT area-stream key concelho "<LI><A HREF=%"ARQS/arq%d(arqind).html%">%g(temp)</A>%n"
  CLOSE area-stream key concelho

ELEMENT quadro
  OUTPUT "<P>%n<H3>Quadro:</H3>%n%c"

ELEMENT desarq
  OUTPUT "<P>%n<H3>Descrição:</H3>%n%c"

ELEMENT liga
  OUTPUT "%c"


DOCUMENT-END
  REPEAT OVER area-stream
    OUTPUT "<h2>Entrys of  '" || 
           key of area-stream ||
           "':</h2>%n<ul>%n%g(area-stream)</ul>%n"
  again